@echo off

:: BatchGotAdmin
:-------------------------------------
REM  --> Check for permissions
>nul 2>&1 "%SYSTEMROOT%\system32\cacls.exe" "%SYSTEMROOT%\system32\config\system"

REM --> If error flag set, we do not have admin.
if '%errorlevel%' NEQ '0' (
    echo Requesting administrative privileges...
    goto UACPrompt
) else ( goto gotAdmin )

:UACPrompt
    echo Set UAC = CreateObject^("Shell.Application"^) > "%temp%\getadmin.vbs"
    echo UAC.ShellExecute "%~s0", "", "", "runas", 1 >> "%temp%\getadmin.vbs"

    "%temp%\getadmin.vbs"
    exit /B

:gotAdmin
    if exist "%temp%\getadmin.vbs" ( del "%temp%\getadmin.vbs" )
    pushd "%CD%"
    CD /D "%~dp0"
:--------------------------------------

setlocal

SET /P varoracleagentpath="Enter path for the existing Oracle agent installation: "
SET varjarpath=%varoracleagentpath%\bin\classes.jar 
SET varcfgfilepath=%varoracleagentpath%\bin\oraconfig.cfg

IF EXIST "%varoracleagentpath%" (
	IF EXIST "%varcfgfilepath%"  (
		net stop TCOracleEvProcessor
		xcopy /y /f .\classes.jar "%varjarpath%"
		xcopy /y /f "%varcfgfilepath%" .\oraconfig.cfg
		net start TCOracleEvProcessor
	) ELSE (
		echo Directory %varoracleagentpath% does not contain valid agent installation
	)
) ELSE (
	echo Directory %varoracleagentpath% does not exist
)

PAUSE
